Revoltijo Elisp (IV)

Primero, la función que pliega las notas, donde nos viene de perlas la función nativa de Org org-narrow-to-element. Nuestro overlay para sustituir al texto de la nota, en este caso, es la palabra «nota», en rojo y encerrada en un recuadro.

(defun pliega-notas-org ()
      (interactive)
      (save-excursion
        (goto-char (point-min))
        (while
            (re-search-forward "^\\[fn:[[:digit:]]" nil t)
          (save-restriction
            (org-narrow-to-element)
            (let
                ((ov (make-overlay (point-min) (point-max)))
                 (nota-plegada (propertize "nota" 'font-lock-face '(:foreground "red" :weight bold :box t))))
              (overlay-put ov 'overlay-nota-plegada t)
              (overlay-put ov 'display nota-plegada))))))

Y para volver a mostrar las notas, simplemente eliminamos el overlay:

(defun muestra-notas-org ()
       (interactive)
       (remove-overlays nil nil 'overlay-nota-plegada t))

Aquí son necesarias algunas triquiñuelas. Primero definimos una función que aplica un par de propiedades de texto entre los argumentos x e y. Los colores que he ecogido, por supuesto, son personales e intransferibles, pero al menos cuadran bien con los dos temas que suelo usar en Emacs, el claro para el día y el oscuro para los trabajos nictálopes.

(defun propiedades-resaltado-nota (x y)
    (put-text-property x y 'font-lock-face '(:background "NavajoWhite" :foreground "DarkMagenta"))
    (put-text-property x y 'front-sticky t))

A continuación, la función que resalta las notas en todo el documento, aplicando las propiedades antes mencionadas como overlay:

(defun resaltado-notas-local ()
    (interactive)
    (save-excursion
      (goto-char (point-min))
      (while
          (re-search-forward "^\\[fn:[[:digit:]]" nil t)
        (save-restriction
          (org-narrow-to-element)
          (let
              ((ov (make-overlay (point-min) (point-max)))
               (resaltado-nota (propiedades-resaltado-nota (point-min) (point-max))))
            (overlay-put ov 'overlay-nota-resaltada t)
            (overlay-put ov 'display resaltado-nota))))))

Ahora, lo complicamos algo más. Esta otra función añade la anterior como variable local al documento. Sólo si no está ya añadida (expresión unless). Así, cada vez que abramos el documento, se conservará nuestro resaltado, ya que los overlays son siempre temporales.

(defun var-local-resaltado-nota ()
    (save-excursion
      (goto-char (point-min))
      (unless (re-search-forward "eval: (resaltado-notas-local)" nil t)
        (add-file-local-variable 'eval '(resaltado-notas-local))
        (save-excursion
          (goto-char (point-max))
          (re-search-backward "# Local Variables:" nil t)
          (newline 5)))))

Y, por último, una función que añade una nota ya resaltada. Por cierto, aquí he tenido que hacer una pequeña triquiñuela no demasiado elegante. Una nota que vamos a escribir es una nota vacía, así que la función org-narrow-to-element no tiene ningún elemento que «aislar». Así que, de forma provisional, se inserta y se elimina un pequeño texto de «bulto», para que el resaltado tenga efecto desde el momento en que empezamos a escribir la nota.

(defun mi-notapie-org ()
    (interactive)
    (org-footnote-action)
    (save-excursion
      (insert "nota"))
    (resaltado-notas-local)
    (var-local-resaltado-nota)
    (save-restriction
      (org-narrow-to-element)
      (goto-char (point-min))
      (replace-regexp "nota" "" nil)))

Uno. La última función tiene un pequeño problema. Si pegamos texto en nuestra nota resaltada (yank), el texto pegado viene con las propiedades de origen, que se sobreescribirán a las del overlay. Por tanto, no aparecerá resaltado hasta que no recarguemos el búfer (revert-buffer). Para prevenir ese comportamiento, podemos definir esta función:

(defun resaltado-yank-notas ()
  (if (org-footnote-at-definition-p)
         (resaltado-notas-local)))

Y hacer que se ejecute justo después de llamar a la función yank. Así:

(advice-add 'yank :after 'resaltado-yank-notas)

Dos. Con esto de los overlays, que da mucho juego, escribí también unas funciones para mostrar las imágenes dentro de un documento de LaTeX o el resultado compilado (y aproximado, ojo) de algunos entornos. El código está en este repo de GitLab.