Org como base de datos: helm-org-ql

El hecho de que Org Mode sea un entorno orientado a los objetos (nodos o «árboles», principalmente) más que a los archivos, propicia disfrutar de una interfaz de alto nivel para Emacs donde podemos librarnos fácilmente de esa servidumbre que los sistemas Unix impusieron hace tiempo hacia el esquema directorio/fichero. Contra ese improductivo corsé ya se habían rebelado en los 80 del pasado siglo aquellas visionarias máquinas Lisp que surgieron del MIT, donde también había nacido Emacs. Y es que el propio Emacs —no lo olvidemos— es una máquina Lisp y un caballo de Troya en un sistema Unix. Por eso, precisamente, «Gnu no es Unix».

Bien, el caso es que los años de uso de Org Mode han llevado a este usuario que aquí escribe a irse desentendiendo poco a poco de los sofocos acerca de en qué directorio me encuentro o qué archivo estoy editando. No es que el desprendimiento sea completo: alguna vez hay que bajar a la sentina a hacer algún apaño. Pero en lo que respecta al entorno de trabajo en sentido estricto, lo que realmente me importa son los nodos o árboles, y navegar por ellos, independientemente de en qué archivos con la extensión .org se hayan sembrado y multiplicado dichas arborescencias. Muchos de estos nodos tienen asociadas carpetas adjuntas mediante org-attach, donde guardo todo tipo de documentos. Para la actividad de recorrer esos paisajes y tener siempre el nodo deseado a mano, Org Mode ya viene de fábrica con unos cuantos recursos muy provechosos. Pero en esta GNUta daremos cuenta de una biblioteca externa utilísima, de esos paquetes que a los pocos minutos de uso uno cae en la cuenta de que ya no puede vivir sin él: me refiero a org-ql y, concretamente, a su versión para la interfaz autocompletiva Helm, helm-org-ql, incluida en el código del paquete. Describiremos a continuación en qué consiste esta biblioteca y comentaremos algunos extremos de mi configuración y personalización en mi archivo de inicio.

org-ql es un ambicioso (a la par que logrado) proyecto de crear un lenguaje de alto nivel para Org a fin de convertir al modo del unicornio en una versátil y potente base de datos, y todo ello con una sintaxis lispiana y legible por humanos. Está escrito por el prolífico autor Adam Porter («alphapapa», en su apodo de GitHub), autor de otros muchos paquetes excelentes. Para programar en Elisp este lenguaje es muy útil, y yo ya tengo hechos algunos pinitos. Un simple ejemplo: imaginemos que queremos desplegar una lista con todos los nodos que tengan el estado «done», y que pertenezcan a los archivos incluidos en la agenda. Esta expresión puede servirnos:

(org-ql-search
  org-agenda-files
  '(todo "DONE"))

helm-org-ql, donde aquí nos centraremos, no es más que la versión de ese lenguaje para el uso cotidiano y la comodidad de Helm. Las búsquedas que podemos lanzar desde allí son muy flexibles. La forma más simple es buscar por cadenas de texto. Por ejemplo, si entre mis nodos de Org quiero localizar aquellos que contienen la palabra «velocípedo», no tengo más que lanzar helm-org-ql y empezar a escribir ese término para que comiencen a mostrarse los resultados. Pero podemos acotar la búsqueda también mediante el uso de comodines muy intuitivos. Supongamos que quiero buscar la palabra «velocípedo» pero sólo en los nodos que tengan el estado «WORKING» y la etiqueta «trabajo». Pues es tan sencillo como escribir en el input de Helm algo como:

velocípedo tags:trabajo todo:WORKING

helm-org-ql viene por defecto con dos acciones sobre el candidato escogido: la principal (y esperable), que nos lleva al nodo en cuestión, y una secundaria (accedida mediante el tabulador, que es el atajo que tenemos en Helm para desplegar el menú de acciones alternativas) para abrir el nodo buscado en un búfer indirecto. Pero yo he ido escribiéndole unas cuantas acciones más, según me iba dictando el uso y la necesidad. Daremos cuenta aquí de ellas, por si algún lector las encuentra útil y quiere adaptarlas a su propio flujo de trabajo. Sólo un pequeño inciso antes de meternos en esa harina. Yo uso, en mi día a día, dos instancias de helm-org-ql: helm-org-ql-agenda-files, que, como su nombre indica, lanza las búsquedas sobre los archivos incluidos en la variable org-agenda-files; y, menos a menudo, helm-org-ql, que busca sólo en el archivo de Org donde estamos. La primera instancia es de donde saco más provecho, pues transciende el concepto «directorio/archivo», como explicamos más arriba.

(defun mi-helm-org-ql-abre-link (marker)
  "abre una entrada candidata en `org-ql' si es un link"
  (interactive)
  (save-window-excursion
    (switch-to-buffer (marker-buffer marker))
    (widen)
    (org-show-all)
    (goto-char marker)
    (org-open-at-point)))

(defun mi-helm-org-ql-link-nativo (marker)
  "Crea un link nativo de Org hacia el candidato en el punto del
cursor"
  (interactive)
  (save-excursion
    (save-window-excursion
      (switch-to-buffer (marker-buffer marker))
      (goto-char marker)
      (setq titulo-link-org-ql (nth 4 (org-heading-components)))
      (call-interactively 'org-store-link)))
  (org-insert-link nil (car (car org-stored-links)) titulo-link-org-ql))

(defun edita-desc-link-reciente ()
  (let ((desc (read-from-minibuffer "Descripción: ")))
    (if (not desc)
        (error "No se ha añadido nueva descripción")
      (when
          (org-in-regexp org-link-bracket-re 100)
        (save-excursion
          (save-restriction
            (narrow-to-region (match-beginning 2) (match-end 2))
            (delete-region (point-min) (point-max))
            (save-excursion
              (goto-char (point-min))
              (insert desc))))))))

(defun mi-helm-org-ql-link-nativo-desc (_)
  (interactive)
  (mi-helm-org-ql-link-nativo _)
  (edita-desc-link-reciente))

(defun mi-helm-org-ql-abre-attachment (marker)
  "abre el cuadro de comandos de `org-attach' sobre el candidato
seleccionado"
  (interactive)
  (switch-to-buffer (marker-buffer marker))
  (widen)
  (org-show-all)
  (goto-char marker)
  (call-interactively #'org-attach))

(defun mi-helm-org-ql-guarda-adjuntos-gnus (marker)
  "Guarda todos los archivos adjuntos del artículo actual de `Gnus'"
  (interactive)
  (switch-to-buffer (marker-buffer marker))
  (widen)
  (org-show-all)
  (goto-char marker)
  (when (not (member "ATTACH" (org-element-property :tags (org-element-at-point))))
    (org-toggle-tag "ATTACH"))
  (let ((atch-dir (org-attach-dir t))
        (art gnus-article-current))
    (gnus-summary-save-parts "." atch-dir art)))

(with-eval-after-load 'helm-org-ql
  (add-to-list 'helm-org-ql-actions '("Abre el candidato como link" . mi-helm-org-ql-abre-link) t)
  (add-to-list 'helm-org-ql-actions '("Abre adjuntos" . mi-helm-org-ql-abre-attachment) t)
  (add-to-list 'helm-org-ql-actions '("Guarda adjuntos de Gnus" . mi-helm-org-ql-guarda-adjuntos-gnus) t)
  (add-to-list 'helm-org-ql-actions '("Crea un link nativo de Org" . mi-helm-org-ql-link-nativo) t)
  (add-to-list 'helm-org-ql-actions '("Crea un link nativo de Org, editando la descripción" . mi-helm-org-ql-link-nativo-desc) t))