EXWM, o GNU Emacs como gestor de ventanas

Partiendo de que ya hemos instalado LXDE y hemos lanzado una sesión a fin de que se nos generen todos los archivos de configuración necesarios, lo primero que tenemos que hacer es decirle a LXDE que use como gestor de ventanas EXWM y no Openbox. De modo que abrimos el fichero ~/.config/lxsession/LXDE/desktop.conf y ponemos:

[Session]
window_manager=emacs

A continuación, en ese mismo directorio, tenemos el archivo autostart, para apuntar las aplicaciones que queremos se inicien automáticamente con cada arranque de sesión. Allí anoté unas cuantas. Y, como no me gusta el panel de LXDE, puse en su lugar a Polybar (que ya venía usando con Bspwm). Pero eso ya va en gustos³. Mi fichero autostart luciría, entonces, tal que así:

@pcmanfm --desktop --profile LXDE
@polybar mibar
@lxpolkit
@redshift-gtk
@nm-applet
@picom -b -C
@dunst

Como se ve, uso el excelente gestor de notificaciones dunst. También añadí luego un script donde incluí una serie de apaños más (remapeo de algunas letras del teclado) que deseo incorporar al inicio de sesión. Y, nada, ya sólo queda iniciar LXDE, y se obra la magia.

No he renunciado al estupendo Rofi, que tengo configurado de la siguiente forma para invocarlo con la secuencia s-d. Una vez abierto se muestra Rofi en modo lanzador, y si pulso la tecla «<», me muestra las ventanas abiertas de las aplicaciones externas:

(exwm-input-set-key (kbd "s-d") (lambda ()
                                    (interactive)
                                    (let
                                        ((rofi "rofi -modi drun,window -show drun -kb-mode-next \"less\" -kb-delete-entry \"control+q\" -show-icons"))
                                      (call-process-shell-command rofi))))

  (push (elt (kbd "s-d") 0) exwm-input-prefix-keys)

Pero, si bien lo mantengo, porque tampoco estorba, al final he optado por crearme mi propio lanzador con Ido, que ha venido a sustituir a helm-run-external-command. Primero definí la función que genera la lista de aplicaciones:

(defun crea-lista-programas ()
  (interactive)
  (seq-mapcat
   (lambda (bin)
     (directory-files bin nil "^[^.]"))
   exec-path))

Y a continuación el lanzador con ido propiamente dicho:

(defun ido-lanzador (comando)
  (interactive  (list (ido-completing-read "$: " (crea-lista-programas) nil t)))
  (start-process-shell-command comando nil comando))

Ver el título de cada aplicación externa en la lista de búferes abiertos, y no sólo su nombre genérico (como «firefox», «gimp», «libreoffice», etc.), era algo ciertamente deseable. Por suerte se puede conseguir si añadimos el siguiente código (tomado de aquí) a nuestro archivo de configuración:

(defun exwm-rename-buffer ()
  (interactive)
  (exwm-workspace-rename-buffer
   (concat exwm-class-name ":"
           (if (<= (length exwm-title) 50) exwm-title
             (concat (substring exwm-title 0 49) "...")))))

(add-hook 'exwm-update-class-hook 'exwm-rename-buffer)

(add-hook 'exwm-update-title-hook 'exwm-rename-buffer)

Si configuramos el firefox (por ejemplo) de manera que abra las nuevas pestañas como ventanas, podemos ver los títulos de todas las pestañas abiertas desde nuestra lista de búferes. Muy cómodo y emacscéntrico.

Para poder salir de la sesión de Lxde de forma segura (en términos de Emacs, quiero decir) incluyo esta función que aconseja la wiki de Arch. Si bien, ojo, hay que requerir antes recentf para evitar un error:

(require 'recentf)

  (defun exwm-logout ()
    (interactive)
    (recentf-save-list)
    (save-some-buffers)
    (start-process-shell-command "logout" nil "lxsession-logout"))

Aunque no está de más guardarse un as en la manga en caso de que tengamos que salir de urgencia desde la consola de comandos. Para esa posible situación tengo definido este alias en mi ~/.bashrc

alias mata_sesion='sudo pkill -9 -u juanmanuel'

Hace poco escribí esta suerte de «salvapantallas», que incluye un reloj analógico (proporcionado por el excelente paquete svg-clock e introduce los primeros versos de la Odisea imitando el mecanografiado humano).

;; Definimos el estilo del texto de la Odisea. Se puede modificar a conveniencia

(defface texto-baskerville
  '((t :family "GFS Baskerville" :height 220))
  "")

;; Los primeros versos de la Odisea. Se puede sustituir por cualquier otro texto

(setq odi-prim-versos "Ἄνδρα μοι ἔννεπε, Μοῦσα, πολύτροπον, ὃς μάλα πολλὰ
πλάγχθη, ἐπεὶ Τροίης ἱερὸν πτολίεθρον ἔπερσε·
πολλῶν δ' ἀνθρώπων ἴδεν ἄστεα καὶ νόον ἔγνω,
πολλὰ δ' ὅ γ' ἐν πόντῳ πάθεν ἄλγεα ὃν κατὰ θυμόν,
ἀρνύμενος ἥν τε ψυχὴν καὶ νόστον ἑταίρων.
ἀλλ' οὐδ' ὣς ἑτάρους ἐρρύσατο, ἱέμενός περ·
αὐτῶν γὰρ σφετέρῃσιν ἀτασθαλίῃσιν ὄλοντο,
νήπιοι, οἳ κατὰ βοῦς Ὑπερίονος Ἠελίοιο
ἤσθιον· αὐτὰρ ὁ τοῖσιν ἀφείλετο νόστιμον ἦμαρ.
τῶν ἁμόθεν γε, θεά, θύγατερ Διός, εἰπὲ καὶ ἡμῖν.")

;; Esta función es para imitar el mecanografiado

(defun imita-tecleo (texto)
  (mapc (lambda (caracter)
      ;; Aquí se puede cambiar la velocidad de `tecleo'
          (sit-for 0.08)
          (insert caracter)
          (when
              (looking-back "\\(.\\)" nil)
            (replace-match (propertize (match-string 1) 'face 'texto-baskerville))))
        texto))

;; La función que activa el salvapantallas.
;; OJO: para que se vea el reloj analógico es necesario tener instalado
;; el paquete `svg-clock'. Para quietar el salvapantallas: pulsar tecla `q'

(defun mi-salvapantallas-reloj-fecha ()
  (interactive)
  (when (get-buffer "*fecha y hora*")
    (kill-buffer "*fecha y hora*"))
  (switch-to-buffer (get-buffer-create "*fecha y hora*"))
      ;; Descomentar la siguiente línea para añadir transparencia
    ;; (set-frame-parameter (selected-frame) 'alpha '(75 . 40))
  (let ((inhibit-read-only t))
    (buffer-disable-undo)
    (erase-buffer)
    (svg-clock-insert 350)
    (insert
     (concat "\n\n\n       " (format-time-string "%A %e de %B de %Y") "\n\n\n"))
    (imita-tecleo odi-prim-versos)
    (view-mode)))

;; Lo siguiente es necesario para recuperar
;; la opacidad al salir del salvapantallas pulsando  `q'
(defun opacidad ()
    (set-frame-parameter (selected-frame) 'alpha '(100 . 100)))

  (advice-add 'View-quit :after #'opacidad)

Y un vídeo de muestra, con un tema oscuro y otro claro (Leuven):

Llevaba un tiempo largo usando EXWM sobre un entorno de escritorio, primero con LXDE y posteriormente con Mate. La experiencia ha sido buena y placentera, desde luego, pero últimamente me apetecía mudar a un arranque de EXWM «puro», sólo con lo configurado en el archivo ~/.xinitrc, tal y como comentábamos más arriba. Por supuesto, en nuestro propio ~/.xinitrc es necesario cargar algunas aplicaciones externas necesarias, como el icono de NetworkManager para la red, el compositor Picom y otras más que queremos arrancar en el inicio de sesión. También he decidido iniciar Emacs como servidor, y cargar EXWM como cliente. En resumidas cuentas, éste sería mi archivo ~/.xinitrc:

xhost +SI:localuser:$USER

export _JAVA_AWT_WM_NONREPARENTING=1

xsetroot -cursor_name left_ptr

# Aplicaciones externas al inicio

/home/juanmanuel/Scripts/./teclado.sh &
/home/juanmanuel/Scripts/./nextcloudcmd.sh &
redshift &
picom &
dunst &
nm-applet &
xfce4-power-manager &
xset r rate 250 30 &
nitrogen --restore &

# iniciamos Emacs

emacs --daemon -f exwm-enable

exec emacsclient -c

Nótese que cargo también un par de scripts propios, uno para sincronizar el cliente de escritorio de Nextcloud (lo hago siempre en la versión línea de comandos, pues el cliente gráfico me resulta intrusivo), y otro para ciertas personalizaciones y remapeos de teclado. También cargo el gestor de fondos de pantalla Nitrogen (de vez en cuando me gusta usar Emacs con una transparencia más o menos translúcida, una frivolidad), el gestor de energía de Xfce, el gestor de notificaciones Dunst y una configuración del comando xset para la ratio de velocidad/repetición del teclado. Después de arrancar todo eso, iniciamos Emacs como servidor y ejecutamos emacsclient. Y una nota importante: antes lo ejecutaba mediante el comando dbus-launch con la opción --exit-with-session, pero en Arch me daba unos problemas horribles de colapso de sesión. Ignoro a qué se debe.

Y una vez editado y guardado en nuestra carpeta HOME el archivo ~/.xinitrc, ya sólo nos queda arrancar desde una tty con el comando startx. Pero si queremos seguir logueándonos con nuestro display manager, podemos hacer un script ejecutable con el contenido de nuestro ~/.xinitrc y guardarlo en la carpeta de binarios /usr/bin/. Posteriormente, añadiríamos un archivo *EXWM.desktop a /usr/share/xsessions, algo así como esto (la línea donde añadir nuestro script ejecutable sería ésta)⁴.

[Desktop Entry]
Name=EXWM
Comment=Executes the .xinitrc script in your home directory
Exec=<mi-script-ejecutable>
TryExec=xinitrcsession-helper
Type=Application

Merecían algo de atención aquí las teclas simuladoras de EXWM, es decir, un tipo especial de atajo que «simula» los atajos típicos de Emacs en la aplicación hospedada. Estoy bastante satisfecho de la siguiente configuración de teclas simuladoras que tengo en mi archivo de inicio (nótese que en mi Emacs tengo configuradas las secuencias M-j y M-SPC como «retroceso» y «control + retroceso», respectivamente. En las teclas simuladoras esos atajos están en las líneas 10 y 11):

 1: (setq exwm-input-simulation-keys
 2:       '(([?\C-b] . [left])
 3:         ([?\C-f] . [right])
 4:         ([?\C-p] . [up])
 5:         ([?\C-n] . [down])
 6:         ([?\C-a] . [home])
 7:         ([?\C-e] . [end])
 8:         ([?\M-v] . [prior])
 9:         ([?\C-v] . [next])
10:         ([?\M-j] . [backspace])
11:         ([?\M- ] . [C-backspace])
12:         ([?\C-m] . [return])
13:         ([?\C-d] . [delete])
14:         ([?\C-y] . [?\C-v]) ;pegar
15:         ([?\C-w] . [?\C-x]) ;cortar
16:         ([?\M-w] . [?\C-c]) ;copiar
17:         ([?\C-k] . [S-end delete])))